To Lecture Notes

CSC 433 -- Apr 17, 2017

Review Exercises

1. How do you do the following with a put statement when writing to a file created by a file statement?
    
   
   1. Go to column 15.   Ans: @15
       
   2. Go to a new line.   Ans: /
       
   3. Print a time variable. Ans: Use one of the time formats, such as TIME. Usually you get better results when you include a field width like TIME9. or TIME10.
       
   4. Hold a line for the next put statement.   Ans: You can use either @ or @@
   
   
2. Which of these statements are executable? Which are declarative?
   

   datalines  drop  file  infile  input  
   keep  label  length  output  put  
   retain  set
   

   Ans:
   

   Executable	Declarative
   input	datalines
   put	drop
   set	file
   	infile
   	keep
   	length
   	retain

   
   
3. Find the errors in this SAS source code file.  The corrected version is also shown.  It uses the kids.txt file as its input file.
    
4. How can you determine the gender from the Erie Marathon file for Project 3?
   Ans: Suppose you have extracted a field named age_gender, which is a character variable which contains an age like 34 or an age with an asterisk 28*. Here are two possibilities:
   

   * Version 1;
   len = length(age_gender);
   if substr(age_gender, len) = "*" then do;
      age = substr(age_gender, 1, len - 1);
      gender = "F";
   end;
   else do;
      age = age_gender;
      gender = "M";
   end;
   
   * Version 2;
   len = length(age_gender);
   if index(age_gender, "*") = 0 then do;
      age = age_gender;
      gender = "M";
   end;
   else do;
      age = scan(age_gender, -1);
      gender = "F";
   end;
   

5. Suppose that the sashelp.class permanent data is trashed on your SAS installation. How can you restore it from the copy on a different computer? Ans:
   

   * To create local copy on a different machine:
   libname local 'c:/datasets/local';
   data local.class;
      set sashelp.class;
   
   * To restore on your machine:
   libname local 'c:/datasets/local';
   data sashelp.class;
      set local.class;
   

6. Using the sashelp.class dataset, plot weight vs. height, using the plotting symbols blue ♂ for male and red ♀ for female. Here is the SAS graphics symbol chart.
   

   data temp;
      set sashelp.class;
      keep Height Weight symb;
      if sex = 'M' then symb = 1;
      else if sex = 'F' then symb = 2;
   
   goptions reset=all;
   symbol1 c = blue h = 2 v = >;
   symbol2 c = red h = 2 v = *;
   proc gplot;
      plot Weight * Height = symb;
   

7. Create the scatterplot in Exercise 11 using sgplot. Note:
   The male and female symbols are not available with ODS graphics.
   Ans: Here is a solution using the default o and + symbols:
   

   ods html style=statistical;
   proc sgplot data=sashelp.class;
      scatter x = Weight y = Height / group = sex;
   

   To choose your own plotting symbols, create an ODS graphics style template as in the Iris2 Example.
    
8. Here are results of an early Cholera study (1894-96):
    
   

   Inoculated	Infected	Count
   0	0	473
   1	0	276
   0	1	66
   1	1	3

   
   Summarize this data using (a) proc freq, (b) proc gchart, (c) proc sgplot. Ans:
   

   data cholera;
      input innoculated $ infected $ count;
      datalines;
   0 0 473
   1 0 276
   0 1  66
   1 1   3
   ; 
   
   proc format;
      value $YESNO "0"="No" "1"="Yes";
   
   proc freq;
      table innoculated * infected / 
         nopercent norow nocol nocum;
      weight count;
      format innoculated $YESNO. infected $YESNO.;
   
   proc gchart;  * Side-by-side bars for innoculated.
      vbar infected / group=innoculated freq=count;
      
   proc gchart;  * Stacked bars for innoculated.
      vbar infected / subgroup=innoculated freq=count;
   
   proc sgplot;  * Side-by-side bars for innoculated.
      vbar infected / group=innoculated 
         groupdisplay=cluster freq=count barwidth=0.8;
   
   proc sgplot;  * Stacked bars for innoculated.
      vbar infected / group=innoculated freq=count;
   

Quiz 3

• Take Quiz3 in groups of 2 or 3.

SGPLOT Scatterplots

• SAS reference for the sgplot procedure.
   
• Look at these sgplot items
   
  
  scatter  ellipse  keylegend  reg  loess  xaxis  x2axis  yaxis  y2axis 
  
  
• Here are some of the builtin styles that are recommended for ods graphs:
   
  

  Style	Output	Comments
  HTMLBLUE	Full Color	White background, optimized for HTML output
  DEFAULT	Full Color	Gray background, optimized for HTML output
  ANALYSIS	Full Color	Yellow background
  STATISTICAL	Full Color	White background, colored fills
  LISTING	Full Color	White background, optimized for color format on white paper
  JOURNAL	Gray Scale	Interior filled areas are gray scale

  
  
• To set the style for the sgplot graph:
  

  ods html style=statistical;
  

• To see the list of all builtin styles:
  

  proc template;
     list styles;
  

• To see detailed settings for a style:
  

  proc template;
     source styles.statistical;
  

• To create your own style, see the Iris2 example. This example uses proc template to define a style that controls the plotting symbols for a scatterplot.

More ODS Graphs

• Look at these ODS Graphics Examples from the Little SAS Book:
   
  
  BarChart   Histogram   BoxPlot   ScatterPlot   Series
  
  
• We already discussed barchart and skatterplot examples, so we only looked at the Series examples on Apr 17.

A Double Axis Graph

• Look at the DoubleAxis Examples.
   
• We did not discuss this example in class on Apr 17.

Information about SAS procs

Statements and Options Used in Many Plots

• The var statement controls which variables are used.
   
• The by statement applies the proc separately to groups of observations, grouped by the values of the by variable.
   
• The where statement applies the proc to only those observations where a condition is true.
   
• The output statement creates an output dataset from the proc.
   
• Use the title and footnote statements to display test at the top and bottom, respectively, of the proc print output.
   
• SAS options for procs
   
  
  data -- specifies the dataset which the proc analyzes or processes.
   
  out -- specifies the output dataset.
  
  
• Example:
  

  proc means data=sashelp.class n mean;
     var age;
     by sex;
     where age < 13;
     label sex='Gender';
  

proc sort

proc print

proc means and proc summary

proc sql

Project 4

• We will discuss the Project 4 Description next week.