To Lecture Notes

CSC 433 -- 4/11/16

Review Exercises

1. How do you clear these windows: Enhanced Editor, Output Window, Log, Results Viewer.
   Ans: Enhanced Editor: Control-A, Delete;
   Output Window and Log: Right Click >> Edit >> Clear All;
   Results Viewer: Click in Results Viewer Window and in the main menu: Edit >> Clear All.
    
2. How does the subsetting if statement work?
   Ans: The subsetting if statement looks like this:
   

   if gender = 'F';
   

   If gender = 'F' is true, the observation is kept in the dataset. If gender = 'F' is false, the observation is deleted.
    
3. How can you convert a value from a numeric type to a character type and vice versa?
   Ans: Here are some examples.  Suppose that s = "123.45" and x = 123.45.
   

   * Converting from character to numeric;
   val = s + 0;
   val = s * 1;
   val = input(s, 6.2); *<-- 6.2 is an informat;
   
   * Converting from numeric to character;
   str = x || "";
   str = put(x, 6.2); *<-- 6.2 is a format;
   

4. How you handle embedded blanks in character values? Try out your solution on this file: states2.txt.
   Ans: Use an ampersand to tell SAS to keep reading a string with embedded blanks. Only stop reading the string if two consecutive blanks are encountered. For instance, here is a data step that does this:
   

   data states;
      infile "c:/datasets/states2.txt";
      length state $ 14;
      input state $ &;
   

5. What is the SAS symbol for concatenation? for exponentiation?
   Ans: Ans: concatenation: ||   exponentiation: **
    
6. What do these informats do?
   

   IB3.  DATE.  ANYDTDTE.  JULIAN.

   IB3. reads a 3 byte integer binary field.
   DATE. reads a date in ddmmmyy, where mmm is a three character month abbreviation, for example 04jul2013.
   ANYDTDTE. reads a time in various formats.
   JULIAN. reads a date in the format yyddd or yyyyddd, where ddd is the number of days since the beginning of the year.
    
7. What does dsd mean in an infile statement?
   Ans: dsd means delimiter sensitive data.
    
8. What is an encoding? List some popular encodings for SAS.
   Ans: An encoding is a method for representing characters in a file on disk. Popular SAS encodings are wlatin1, wlatin2, utf8, utf16-be (Big Endian), utf16-le (Little Endian).

D2L Quizzes

• Take Quiz2 in groups of 2 or 3.

Special SAS Constants

• We already know about character and numeric constants. Here are some special constants that can be used in SAS:
   
  

  Special SAS Constants
  Example	Description
  '25dec2012'd	Date
  '25dec2012:3:45:12pm'dt	Date Time
  '3:45:12pm't	Time
  '09'x  (tab) '0c'x (form feed)	Hex Character

  
  
• Practice Problems:
   
  
  1. Verify that Jan 1, 1960 is the SAS zero date using a SAS special date constant.
      
  2. The world marathon record was broken yesterday (Apr 9) in Berlin by Dennis Kimetto. His time was 2:02.57. Use a SAS special time constant to represent this time.
      
  3. Use the SAS special constant for the tab character to read this tab-delimited file: kids-tab-dlm.txt.

Combining Datasets

• Including a Summary Statistic
   
  
  To use a summary statistic from proc means, like a total or average, in another dataset (called original), use a script like this:
  

  data combined;
     if _n_ = 1 then set summary;
     set original;
  

  See the InsertSum Example.
  
  
• Stacking Two Datasets
   
  

       kidsa             kidsb            stacked
  ============      ============     =============        
   3 Tom  M 13      2 Scott M  9      3 Tom   M 13
   7 Sue  F 11  +   6 Eve   F 11  =   7 Sue   F 11  
   9 Will M  9      8 Jane  F  7      9 Will  M  9
  11 Jen  F  8                       11 Jen   F  8
                                      2 Scott M  9
                                      6 Eve   F 11  
                                      8 Jane  F  7
  

  Use these statements to stack two datasets:
  

  data stacked;
     set kidsa kidsb;
  

  The builtin logical in variables can be used to identify the source of each line in the resulting stacked dataset:

  data stacked;
     set kidsa (in=a) kidsb (in=b);
     if a then source='kidsa';
     if b then source='kidsb';
  

  See the Union Example that shows the result of stacking and interleaving two datasets.
   
• Interleaving Two Datasets
   
  

       kidsa             kidsb        interleaved
  ============      ============     =============        
   3 Tom  M 13      2 Scott M  9      2 Scott M  9
   7 Sue  F 11  +   6 Eve   F 11  =   3 Tom   M 13  
   9 Will M  9      8 Jane  F  7      6 Eve   F 11
  11 Jen  F  8                        7 Sue   F 11
                                      8 Jane  F  7
                                      9 Will  M  9
                                     11 Jen   F  8   
  

  Use these statements to interleave two datasets. The two datasets must be sorted by the by variable for this to work.
  

  data stacked;
     set kidsa kidsb;
        by number;
  

  See the Union Example that shows the result of stacking and interleaving two datasets.
   
• Match Merging Two Datasets
   
  

      kids          teachers      match_merge
  ============     =========      ===========
  1 Tom   M 45                    1 Tom   M 45 Patel
  2 Sue   F 45     45 Patel       2 Sue   F 45 Patel
  3 Jen   F 67  +  67 Chen    =   3 Jen   F 67 Chen
  4 Scott M 93     93 Suarez      4 Scott M 93 Suarez
  5 Eve   F 93                    5 Eve   F 93 Suarez
  6 Jane  F 93                    6 Jane  F 93 Suarez
  

  Use these statements to form the join of two datasets. This is called a match merge in SAS. Again, the two datasets must be sorted by the join variable for the match merge to work.

  data merged;
     merge kids teachers;
        by teacher_number;
  

  See the MatchMerge Example.

Permanent SAS Datasets

• Permanent SAS datasets
   
  
  1. reside on disc in a designated folder.
      
  2. each have a two part name:
     

     data usa.illinois;
     

  3. is accessed using a set statement like a temporary dataset:
     

     set usa.illinois;
     

• See the PermDS Example.
   
• Use proc contents to check out some of the datasets in the sasuser library. Pick out one of these datasets to print.
   
• Temporary SAS datasets have a two-level name starting with work, for example, work.students.
   
• A temporary dataset can be referenced with its two level name, for example, work.students, or by leaving off the work prefix and simply calling it students.

Arrays

• Arrays are used when you want to perform the same calculation for many variables. A loop can be used to repeat the calculation.
   
• For example:
  

  array exam (7) q1 a2 a3 a4 a5 midterm final;
  do i = 1 to 7;
     if exam(i) = . then exam(i) = 0;
  end;
  

• Square brackets [ ] or curley braces { } can be used instead of parentheses ( ) to define the size of the array or lookup array items.
   
• Look at the Quiz5 Example.
   
• Look at the Grades Example.

Project 3

• Look at the Project 3 description.
   
• InsertSum Example
   
• The INPUT function can be used to convert a string to a number.
   
• Look at the SAS SCAN function in the Selected SAS Functions Reference.
   
• Example: Use the scan function to read the name, gender, and age from the following data lines:
  

  ID   name,gender,age phone
           11111111112222222222333
  12345678901234567890123456789012
  3333 James,M,13     222/333-4444
  4444 Elizabeth,F,11 555/666-7777
  
  Ans:
  
  data test;
     infile "c:/datasets/data.txt" firstobs=4;
     input id 1-4 info $ 6-19 phone $ 21-32;
     name = scan(info, 1, ",");
     gender = scan(info, 2, ",");
     age = input(scan(info, 3, ","), 2.);
  

SASHELP Datasets

• SAS provides over 200 sample permanent datasets in the sashelp library.
   
• Use proc contents to obtain information about the sashelp datasets:
  

  proc contents data=sashelp._all_;
  

• This document describes the Sashelp datasets:
   
  
  support.sas.com/documentation/tools/sashelpug.pdf
  
  
• Printing the first 15 lines of a dataset with proc print is a good way to get a feel for the dataset.
   
• Look at the SASHELP datasets class and mileages.

SAS Graphics

• Graphics in SAS fall come in three types:
   
  
  1. Low resolution typewriter graphics, for example proc plot.
      
  2. Traditional SAS/GRAPH graphics, for example proc gplot.
      
  3. ODS (Output Delivery System) graphics, for example proc sgplot.
  
  
• Karl Pearson (1857 to 1936) was one of the founders of the discipline of mathematical statistics. He applied statistics to human measurements. One of his classic datasets (pearson.txt) is from a circa 1903 experiment where he compares the heights of fathers with the heights of their sons.
   
• See the Pearson Example.
   
• Here are the statements used to generate the scatterplots in the Pearson Example.  Each scatter plot plots the son's height on the y-axis vs. the father's height on the x-axis.  Note that the scatterplots automatically pick up the labels defined in the data step.
  

  * Typewriter Graphics;
  proc plot;
     plot son*father; 
     
  * SAS/Graph;
  proc gplot;
     plot son*father;
   
  * ODS Graphics;  
  proc sgplot;
     scatter x=father y=son;
  

Project 4

• Look at the Project 4 Description.
   
• Run the Smoke1 and Smoke2, and Smoke3 Examples.  These examples use data from the Metro Chicago Information Center (MCIC).
   
• See this online documentation for specifying patterns for the following SAS/GRAPH procs: gchart (two and three dimensional bar graphs, pie and star charts), gcontour, gmap, gplot (areas beneath or between plotted lines).

PROC GPLOT Scatterplots

• To customize plotting symbols, use symbol, symbol2, symbol3, ... statements.
   
• For example, the following statement defines symbol1:
  

  symbol1 value=star height=0.5 cm color=red interpol=none
  

  The plotting symbol is a star, the height of the symbol is 0.5 cm, the color of the symbol is red, the font for the symbol is arial, the interpolation method is none.
   
• Here are the allowed values for some of the symbol options. The abbreviation is shown in parentheses:
   
  
  value (v)   Sets the symbol to be used plotting. Possible values include keyboard symbols enclosed in quotes or these special symbols not enclosed in quotes:
   
  
   
  color (c)   Sets the color of a symbol.
   
  height (h)   Sets the height of a symbol. The units can be specified after the height. If units are not specified, the height is a multiple of the default character size. Other units can be specified with in the goptions statement.
   
  interpol (i)   Sets the interpolation method.  Some interpolation options are NONE, JOIN, NEEDLE, HILOxxx (x can be T, B, C, or J).
  
  
• For more detailed information about specifying symbols, see the SAS/GRAPH online reference on the symbol statement.
   
• See the Pearson2 Example to see how to specify the horizontal and vertical axes for a scattergram.

GOPTIONS for SAS/GRAPH

• Use goptions to control plot details.
   
• Here are example goptions statements
  

  goptions reset=all;
  goptions hsize=5 vsize=6 colors=(maroon navy black) 
     csymbol=purple border ctitle=green interpol=needle;
  

  These options do the following
   
  
  1. Reset all graphics settings to defaults.  More specific reset options exist, such as
     

     goptions reset=symbol;
     

     This statement resets only options that apply to plotting symbols.
      
  2. Set the size of the plot to 5inches x 6inches.
      
  3. Sets the list of active colors to maroon, navy, and black.  These active colors are used for symbols if not overrridden by more specific settings for symbol colors.
      
  4. Sets the color of symbols to purple. This color is overridden by specific symbol statements.
      
  5. Draws a border around the plot.
      
  6. Sets the color of the title to green.
      
  7. Sets the interpolation method to needle (connect each plotted point to the bottom of the plot).
  
  The SAS/Graph Reference for goptions.

The Iris Examples

• The sashelp.iris dataset (R.A. Fisher 1936) consists of four variables, all measured in millimeters: Petal Length, Petal Width, Sepal Length, Sepal Width. This image shows where the petal and sepal are located on a flower.
   
  
   
  These four variables were measured on four different iris species: Setosa, Versicolor, and Virginica. The following four examples graph the Iris dataset:
   
  
  1. Iris1   Graphs a scatterplot of the Iris dataset using the SASGRAPH proc gplot.
      
  2. Iris2   Graphs a scatterplot of the Iris dataset using the ODS proc sgplot.
      
  3. Iris3   Graphs a matrix of pairwise scatterplots the Iris dataset using the ODS proc sgscatter.
      
  4. Iris4   Graphs a three-dimensional plot of the Iris dataset using the SASGRAPH proc g3d.
      

More about Missing Values

• The infile statement flowover, missover, truncover, and pad are popular options for variable length lines:
   
  
  flowover (default) -- If the end of line is reached and not all variables have been assigned, jump to a new line to complete the variable assignments.
   
  missover -- If the end of line is reached and not all variables have been assigned, set all unassigned variables to missing and jump to a new line.
   
  stopover -- If the end of line is reached and not all variables have been assigned, stop processing.
   
  truncover -- If the end of line is reached and not all variables have been assigned, set all unassigned variables using the partial information obtained from the short line, then jump to a new line.
   
  pad -- Pad each input line with blanks so all lines are the same length. This is slower than truncover.
  
  
• This paper by Randall Cates discusses more details about how missing values are generated, including the statements flowover, stopover, scanover, pad.
   
• The Missing Examples Column and List illustrate the examples in the Randall Cates paper.
   
• Try replacing truncover in the infile statement of the StateRegions Example with flowover and missover.
   
• Here is a version that uses the ampersand ( ) specifier to read embedded blanks in the state names from the input file states2.txt:
  

  data states;
     infile "c:/datasets/states2.txt" truncover;
     input name $ &;
     
  proc print;