* Sgpanel Example
  Show four sgpanel examples;

options ls=64 nodate pageno=1;

* Example 1 -- Create a panel of loess curves;
title1 "Cholesterol Levels for Age > 60";
proc sgpanel data=sashelp.heart(
    where=(AgeAtStart > 60)) ;
    panelby sex / novarname;
    loess x=weight y=cholesterol / clm;
run;

* Example 2 -- Create a panel of vertical bar charts;
title1 "Product Sales";
proc sgpanel data=sashelp.prdsale;
    panelby quarter;
    rowaxis label="Sales";
    vbar product / response=predict stat=mean
                   transparency=0.3;
    vbar product / response=actual stat=mean
                   barwidth=0.5 transparency=0.3;
run; 

 * Example 3 -- Create a panel of box plots 
                in a lattice layout;
title1 "Distribution of Cholesterol Levels";
proc sgpanel data=sashelp.heart;
    panelby weight_status sex / layout=lattice
                                novarname;
    hbox cholesterol;
run; 

* Example 4 -- Create a panel of cells with a 
  histogram and a normal density curve;
title1 "Weight Distribution in the Heart Study";
proc sgpanel data=sashelp.heart noautolegend;
    panelby sex / novarname;
    histogram weight;
    density weight;

run;
quit;