* Treatments Example

  Show various tables generated by 
  proc tabular
  
  Reference: 
  http://www.ats.ucla.edu/stat/sas/faq/tabulate.htm;

options ls=70 nodate pageno=1;
data treatments;
   infile 'c:/datasets/treatments.txt' firstobs=2;
   input treat visit ptn score1 score2;

proc print;
   title 'treatment dataset';

proc tabulate data=treatments;
  title 'Table 1';
  class treat ptn;
  var score1;
  table ptn='Patient id', 
     mean=' ' * score1='Drug A, average score over all visits' *
        treat='Treatment' * F=10. 
     / rts=13;
run;

proc tabulate data=treatments;
  title 'Table 2';
  class ptn treat visit;
  var score1;
  table ptn='Patient Id',
        score1='Drug A'*treat*visit*F=6. / rts=13;
run;

proc tabulate data=treatments;
  title 'Table 3';
  class ptn treat visit;
  var score1;
  table ptn='Patient Id',
        sum=' '*score1='Drug A' * treat=' ' * 
           visit=' ' * F=6. / rts=13;
run;

proc format;
  value visit 1='Visit 1' 2='Visit 2' 3='Visit 3';
  value tr 1='Therapy 1' 2='Therapy 2';
run;

proc tabulate data=treatments;
  title 'Table 4';
  class ptn treat visit;
  var score1 score2;
  table ptn='Patient id', 
     mean=' ' * score1='Drug A' * treat='' *
        visit='' * F=10./ rts=13;
  format treat tr. visit visit.;
run;

proc tabulate data=treatments noseps;
  title 'Table 5';
  class treat ptn;
  var score1;
  table ptn='Patient id', 
        mean='' * score1='Drug A, average score over all visits' * treat='' * 
           F=10. / rts=13;
  format treat tr.;
run; 

proc tabulate data=treatments;
  title 'Table 6';
  class ptn treat visit;
  var score1;
  table treat='Treatment' * ptn='Patient id', 
        mean='Average Score from all visits' * 
           score1='Drug A' * F=10. / rts=25;
  format treat tr.;
run; 

proc tabulate data=treatments;
  title 'Table 7';
  class ptn treat visit;
  var score1;
  table ptn='Patient id',
     mean=' ' * score1='Drug A' * treat='' *
        visit='Visit' * F=3. / rts=13;
  format treat tr.;
run; 

proc format;
  value vi 1='3/20' 2='8/30' 3='11/03';
run;

proc tabulate data=treatments;
  title 'Table 8';
  class ptn treat visit;
  var score1 score2;
  table ptn='Id #',
     mean=' '*score1='Drug A'*treat=''*visit=''*F=6.
     sum=' '*score2='Drug B'*treat=''*visit=''*F=6. / 
     rts=6.;
  format treat tr. visit vi.;
run;

proc tabulate data=treatments;
   title 'Table 9';
   class ptn treat visit;
   var score1 score2;
   table treat='Treatment' visit='Visit',
      mean=' '*score1='Drug A'*ptn='Patient Id';
   format treat tr. visit vi.;

data miss;
  set treatments;
  if ptn=4 then score1=. ;
run;

proc tabulate data=miss;
  title 'Table 10';
  class ptn visit;
  var score1;
  table ptn='Patient Id',
     mean=' ' * score1='Drug A' * 
        visit='Visit'/ misstext=[label="Missing"] rts=25.;
  format visit vi.;
run;

quit;