* Pendul Example -- pendul.sas source code;

options linesize=70 nodate;
data pendul;
   infile 'c:/datasets/pendul.txt' firstobs=2;
   input length period;
   len = length * 0.0254;
   sqrtlen = sqrt(len);
   per = period / 30;
   lenlen = len * len;
   loglen = log(len);
   logper = log(per);
   keep len per sqrtlen lenlen loglen logper;
   label len = 'Length of Pendulum (meters)'
         per = 'Period of Pendulum (seconds)'
         sqrtlen = 'Square Root of Period'
		 lenlen = 'Len * Len'
         loglen = 'Log of Length'
         logper = 'Log of Period';

proc print;
   title 'Transformed Variables';

proc gplot;
   plot per * len;

* Model 1: Simple Linear Regression;
proc reg data=pendul;
   title 'Model 1: Simple Linear Regression';
   model per=len / clb;
   plot r.*p. r.*nqq.;

* Model 2: Quadratic Regression;
proc reg data=pendul;
   title 'Model 2: Quadratic Regression';	
   model per=len lenlen / clb;
   plot r.*p. r.*nqq.;

* Model 3: Transform x with Square Root ;
proc reg data=pendul;
   title 'Model 3: Transform x with Square Root';	
   model per=sqrtlen / clb;
   plot r.*p. r.*nqq.;

* Model 4: Log-log Transform;
proc reg data=pendul;
   title 'Model 4: Log-log transform';	
   model logper=loglen / clb;
   plot r.*p. r.*nqq.;
   	 
run;
quit;